*  JieJie Microelectronics P-Spice Model Library
*  Filename:           JMSH0401CG_P v.20230424.txt
*  Product Name:       JMSH0401CG (PDFN5x6-8L)
*  Configuration:      Single N-channel Device
*  Data Sheet Rev.:    1.0
*  Release Date:       Apr25, 2023
*  Junction Temp (Tj): -40C ~ 150C
******************************************************************************************************
*  This model is designed as a tool to assist end user(s) to evaluate the performance
*  of the particular SGT MOSFET (named above) released by JJMSH(R).  It has been
*  verified for function and timing integrity with the commercially available EDA simulat-
*  ion tools. End-user(s) is/are advised to take the best engineering practice (e.g.
*  bread-boarding, laboratory measurement) for the full evaluation.
*
*  Despite of the best effort on engineering & verification, Jiangsu JieJie Microelectronics Co.,
*  Ltd. ("JJM") does not provide any warranty nor take any liability to the results and
*  their effects whatsoever from the simulation run of this model by the end-user(s).
*  While this model may be updated at appropriate times in the future without prior
*  notice, JJM does not assume the sole responsibility for update. 
*
.subckt JMSH0401CG D G S 
M1 1 2 3 3 NMOS L=1E-006 W=1E-006
Vmonitor D 18 0
RD 18 1 0.0006
RS S 3 1E-006
RG G 17 2.0
CGS 3 G 8.94e-10
EGD 12 0 2 1 1
Etemp 17 2 VALUE = {(-0.00425*(TEMP-25))+((-6.41025E-6)*(TEMP-25)^2)}
Gtemp 1 3  VALUE = {I(Vmonitor)*((TEMP+273)/(298)-((TEMP+273)/(298))^2.9)}
VFB 14 0 0
FFB 2 1 VFB 1
CGD 13 14  2e-9
DDG 15 14 DCGD
R2 12 15 1
D2 15 0 DLIM
DSD 3 D DSUB
RR 13 0 1
D1 12 13 DLIM
Cds D 3 Cbreak 8.54877E-9
.MODEL Cbreak CAP (C=1 VC1= -0.04021 VC2 = 4.73562E-4)

.model NMOS NMOS
+LEVEL = 3     
+VMAX = 1.0752E9               ETA = 1.21E-4  
+VTO = 2.833741                  TOX = 1.043684E-9             NSUB = 9.6E19  
+KP = 341.62235                   U0 = 424                      KAPPA = 0.178        
+GAMMA = 6.09542E-2            PHI = 0.761892               THETA = 1.95687E-2            
+DELTA = 159.494503                   

.model DCGD D
+CJO = 6E-10                   VJ = 11                       M = 1.65     
                   
.model DSUB D
+IS = 2.229914E-12             N = 0.96675                   RS = 2.568472E-3           
+BV = 45        
+xti = 2.521391           
           
.model DLIM D
+IS = 1E-4       
.ends JMSH0401CG


******************************************************************************************************
*  Copyright (C) 2021 JJM. All rights reserved.
******************************************************************************************************